a!sblQuery() Function

Retrieves records from Siebel.

Syntax

a!sblQuery( scsExternalSystemKey, usePerUserCredentials, hostname, port, enterpriseApp, appManager, language, parameters, sort)

Common Parameters:

scsExternalSystemKey: (Text) The key from the Third Party Credentials admin console page that corresponds to the set of credentials that should be used to authenticate.

usePerUserCredentials: (Boolean) If true the credentials set in the Third-Party Credentials settings page by the current user running the expression will be used. If false the site-wide credential values will be used.

hostname: (Text) The hostname of the Siebel server. For example, siebel.example.com.

port: (Number (Integer)) The port the Siebel server is listening on. For example, 2321.

enterpriseApp: (Text) The enterprise application of the target system. For example, "SBA_82".

appManager: (Text) The active application manager of the target system. For example, "SSEObjMgr_enu".

language: (Text) The target system language. For example, "enu".

Specific Parameters:

parameters: (Any Type) The records to query, given as a dictionary with the field structure of the Siebel Business Component and Business Object.

sort: (Any Type) The sort order to apply to the query, given as a dictionary with field names based on the fields of the Business Object and values of "ASCENDING" or "DESCENDING".

Returns

The function returns the standard connector result dictionary described in the main Connectors page.

If successful, the result field contains an array of dictionaries with the Siebel records that match the given query parameters, sorted according to the given sort parameter.

Notes

If called multiple times in the same expression with the same parameters, only one query is made to Siebel when the expression is evaluated and the result is reused for each identical call. This caching only applies within a single expression evaluation. Return values are not cached in separate expressions, or in separate evaluations of the same expression.

Examples

Display Orders from Siebel

Copy and paste the expression into the INTERFACE DEFINITION in EXPRESSION MODE, save it, then call the interface in a Tempo Report to test.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
=load(
  local!pagingInfo: a!pagingInfo(startIndex: 1, batchSize: 10),
  local!queryResult: a!sblQuery(
    scsExternalSystemKey: cons!SBL_SCS_KEY,
    usePerUserCredentials: true,
    hostname: cons!SBL_HOSTNAME,
    port: cons!SBL_PORT,
    enterpriseApp: cons!SBL_APP,
    appManager: cons!SBL_APP_MANAGER,
    language: cons!SBL_LANGUAGE,
    parameters: {
      'Order Entry (Sales)': {
        'Order Entry - Orders': {
          "Id",
          "Order Number",
          "Status",
          "Order Type"
        }
      }
    },
    sort: {}
  ),
  with(
    local!datasubset: todatasubset(
        if(local!queryResult.success, local!queryResult.result.Result, {}),
        local!pagingInfo
    ),
    if(local!queryResult.success,
      a!gridField(
        totalCount: local!datasubset.totalCount,
        columns: {
          a!gridTextColumn(
            label: "Id",
            data: index(local!datasubset.data, "Id", ""),
            links: a!forEach(
              items: local!datasubset.data,
              expression: a!dynamicLink(value: fv!item, saveInto: ri!selectedItem)
            )
          ),
          a!gridTextColumn(
            label: "Order Number",
            data: index(local!datasubset.data, "Order Number", "")
          ),
          a!gridTextColumn(
            label: "Status",
            data: index(local!datasubset.data, "Status", "")
          ),
          a!gridTextColumn(
            label: "Order Type",
            data: index(local!datasubset.data, "Order Type", "")
          )
        },
        value: local!pagingInfo,
        saveInto: local!pagingInfo,
        rowHeader: 2
      ), 
      a!textField(
        label:"Error",
        readonly: true,
        value: local!queryResult.error.title
      )
    )
  )
)
FEEDBACK